אופיס 365 כיצד לשלוח מייל מאקסס באמצעות אאוטלוק, בתוספת חתימה?

marlan · 27/2/17

שלום,

ראשית, נחשפתי לפורום הזה רק ביימים האחרונים, לאחר כמה שנות פיתוח באקסס. אחלה דברים יש כאן, רלוונטיים לגמרי לצרכים שלי, חבל שלא הכרתי קודם...
מקווה לקבל כאן עוד, וגם לתרום את תרומתי הדלה.

אני מנסה ליצור טיוטות מייל מוכנים לשליחה, אלא שחסרה בהם החתימה.

להלן הקוד:

קוד:

Public Sub SaveDraftToOutlook(oApp As Outlook.Application, _
                                    strSubject As String, _
                                    Body As String, _
                                    strTo As String, _
                                    strCC As String, _
                                    strBCC As String, _
                                    Atts As Variant, _
                                    Optional HtmlFormat As Boolean = True)
    Dim oMail As MailItem
    Dim i As Integer
    Dim TempHtml As String, TempBody As String
    
    Set oMail = oApp.CreateItem(olMailItem)
    If HtmlFormat Then
        TempBody = Replace(Body, vbCrLf, "</p>")
        TempHtml = Replace(oMail.HtmlBody, "<body>", "<body>" & TempBody & "</p>")
        oMail.HtmlBody = TempHtml
    Else
        oMail.Body = Body
    End If
    oMail.Subject = strSubject
    oMail.To = strTo
    oMail.CC = strCC
    oMail.BCC = strBCC
     
    If IsArray(Atts) Then
        For i = 0 To UBound(Atts)
            If FileExists(CStr(Atts(i))) Then _
                oMail.Attachments.Add CStr(Atts(i))
        Next i
    Else
        If FileExists(CStr(Atts)) Then _
            oMail.Attachments.Add CStr(Atts)
    End If
    oMail.Save
'   oMail.Send - לשליחה אוטומטית, כרגע מחוק
    Set oMail = Nothing

End Sub

הפונק' מיועדת לשלוח כמות של מיילים, לכן מקבלת אוביקט Outlook קיים, ולא מייצרת אחת עבור כל טיוטת מייל.

בתחילה חשבתי כי החתימה נדרסת, לכן אני מוסיף את ה-Body אמור ה-html. אולם מעיון בפורומים אחרים אני מבין כי החתימה לא מוספת כלל. עד לפתיחת ההודעה.
במקרה שלי לא ראיתי שזה עזר: פתיחה אוטומטית או ידנית של המייל לא הוסיה את החתימה.

מכירים פתרון?

תודה מראש!

marlan · 1/3/17

מצאתי פתרון:

קוד:

Public Sub SaveDraftToOutlook(oApp As Outlook.Application, _
                                    strSubject As String, _
                                    Body As String, _
                                    strTo As String, _
                                    strCC As String, _
                                    strBCC As String, _
                                    Atts As Variant)
                                    
    Dim oMail As MailItem
    Dim i As Integer
    Dim TempHtml As String, TempBody As String
    
    Set oMail = oApp.CreateItem(olMailItem)
    oMail.Display' כאן למעשה מוספת החתימה למייל
    If oMail.BodyFormat = olFormatHTML Then
        TempBody = Replace(Body, vbCrLf, "</p>")
        TempHtml = oMail.HtmlBody
        oMail.HtmlBody = TempBody & TempHtml
    Else
        TempHtml = oMail.Body
        oMail.Body = Body & TempHtml
    End If
    MsgBox oMail.HtmlBody
    oMail.Subject = strSubject
    oMail.To = strTo
    oMail.CC = strCC
    oMail.BCC = strBCC
     
    If IsArray(Atts) Then
        For i = 0 To UBound(Atts)
            If FileExists(CStr(Atts(i))) Then _
                oMail.Attachments.Add CStr(Atts(i))
        Next i
    Else
        If FileExists(CStr(Atts)) Then _
            oMail.Attachments.Add CStr(Atts)
    End If
'   oMail.Send
    oMail.Save
    oMail.Close olSave
    Set oMail = Nothing

End Sub

הטקסט בפתרון זה אינו מעוצב, והלקוח יכול לעצב את הטיוטה הכרצונו.
פתרון לא מיטבי לסדרת שליחות... אשמח אם מישהו ישפר אותו

תודה!